Faizan Samdani, Andrei Har, Anson Yap, Husnain Zahid Malik, NARENDRAN

Published August 16, 2023

Smart Greenhouse Automation System

An automated Wi-Fi connected greenhouse status monitoring and control system for soil moisture, temperature, humidity and light intensity

IntermediateFull instructions provided24 hours503

Things used in this project

Hardware components

NodeMCU ESP8266 Breakout Board

Base Board for NodeMCU V3

SparkFun Soil Moisture Sensor (with Screw Terminals)

DHT11 Temperature & Humidity Sensor (4 pins)

LDR, 5 Mohm

Through Hole Resistor, 680 ohm

Resistor 10k ohm

1N4007 – High Voltage, High Current Rated Diode

LED (generic)

Axial Fan, 5 V

Micro Submersible Water Pump DC 3V-5V

Digilent WS2812 Addressable LED Strip

Seeed Studio Grove - 2-Channel SPDT Relay

ControlEverything.com 1-Channel Signal Relay 1A SPDT I²C Mini Module

Breadboard (generic)

4xAA battery holder

AA Batteries

9V Battery Clip

9V battery (generic)

2x18650 Battery Holder with DC Jack

3.7V 2000mAh Li-Ion Battery

Jumper wires (generic)

Software apps and online services

Arduino IDE

Blynk

Hand tools and fabrication machines

Drill / Driver, Cordless

Hot glue gun (generic)

Wire Stripper & Cutter, 18-10 AWG / 0.75-4mm² Capacity Wires

Scissor, Electrician

Tape, Electrical

Tape, Double Sided

Story

Greenhouses are controlled environments used for cultivating plants, providing shelter from external weather while allowing for tailored conditions. However, traditional greenhouse management relies heavily on manual intervention for tasks like temperature, irrigation, and ventilation, which can be time-consuming and error-prone. Designing an automatic system for greenhouses would enhance efficiency by precisely regulating factors like temperature, humidity, and soil moisture, leading to optimized plant growth, resource conservation, reduced labor demands, and improved crop yields.

Microprocessors and microcontrollers are used to operate embedded systems in a variety of devices, including cars, robotics, office equipment, and household appliances and the microcontroller used to design this system is a NodeMCU ESP8266.

The major goal is to build a low-cost Smart Greenhouse Automation System that can regulate the light and water the plants on its own as needed with the objective of collecting, analyzing, and processing data in order to improve production parameters, increase output, and prevent problems like sicknesses in plants. This will be accomplished by gathering data from sensors and using a few actuators to act independently on the environment around the plants.

The basic system is outlined in this hackster, which is built on the concept of an interconnected, Smart Greenhouse Automation System and makes use of essentially the same technology. It will be linked to Blynk app so that it can access your data right on your mobile device.

Soil Moisture Sensor & Water Pump Control

(Faizan Samdani - TP062706)

The soil watering system of the greenhouse uses a soil moisture sensor and a submersible water pump to control the moisture level of the soil. In this system, the soil moisture sensor collects the moisture percentage of the soil once every 5 seconds, and the water pump is activated based on the moisture threshold. If moisture percentage of the soil is more than 60%, the water pump is off but if the moisture percentage is less than 60%, the water pump is activated by a relay for 500 ms.

The sensor used in this system is a YL-69 and YL-38 soil moisture sensor. The probes of the sensor are buried in the soil and connected to the module board. The Vcc of the moisture sensor is connected to a digital pin on the NodeMCU ESP8266, and its done to control the activation of the sensor. The analog pin of the sensor is first connected to a diode and then to the analog pin of the ESP8266. A single channel relay is used to control the water pump and the pump is powered by 3x AA Batteries that are 1.5V each, and both the pump and the battery pack are connected to the normally open (NO) port of the relay.

Soil Moisture Sensor & Water Pump Control Circuit

Temperature and Humidity Sensor & Fan Control

(Andrei Har Ee Cheng - TP057971)

The temperature and humidity are a significant variable for the livelihood of plants, as they simulate the environment and ambience for the plant. As such, these two variables are measured by using the DHT-11 sensor, which collects data for the temperature and moisture of the environment. The DHT-11 was placed inside the greenhouse along with the plant to ensure that the data gathered is accurate to the conditions surrounding the plant. The DHT-11 connects to the NodeMCU by connecting VCC to the 3V3 pin and connecting DATA to D8.

To control these variables, a fan was installed into the greenhouse as a means of intaking air to control the temperature and humidity. The fan is programmed to turn on when certain conditions are met, which in this case are if either the temperature exceeds 30 degrees celsius or if the humidity exceeds 85%. The fan is connected to a 2-channel relay, which is connected to 4xAA batteries that power the fan through the relay.

Temperature and Humidity Sensor & Fan Control Circuit

Light Intensity Sensor & LED Lighting Control

(Muhammad Husnain Zahid - TP058676)

A Light Dependent Resistor (LDR) will be used to measure the light intensity. As soon as the light intensity drops below 25%, the LDR will detect it. When the light intensity falls below a threshold—set at 25%—the high intensity LED strip will switch on for a predetermined period of time, and by doing this, we will be able to provide the plants the ideal length of light each day, significantly accelerating development while using the least amount of energy.

Light Intensity Sensor & LED Lighting Control Circuit

Wi-Fi Connectivity & GUI Dashboard

(Anson Yap Ming Wei - TP059675)

Wi-Fi Connectivity & Graphical Dashboard is made possible between Arduino and Blynk App. The smart greenhouse automated system consist a few different sensors, each sensor has different ports. These different ports are then coded and connected with the Blynk app which allows the user to monitor the plant remotely through Wi-Fi connectivity. The following figure shows the graphical user interface of the Blynk app.

Blynk App Graphical User Interface

The above is the graphical user interface for the Blynk app. The GUI displays data of surrounding temperature (C), surrounding humidity (%), ambient light intensity (%), soil moisture (%), state of the fan (ON/OFF), state of the pump (ON/OFF), and state of the lights (ON/OFF). For example, if user observes the soil moisture is too low, the pump will run at intervals to make sure the soil moisture is moist again.

Different sensors transmit data in different ports, so it was possible to assign different ports of the data collected into the Blynk app to process. This it converted the digital signals into viewable data for the user.

Final Design

Smart Greenhouse Automation System

Smart Greenhouse Automation System Circuit

// Include required libraries
#define BLYNK_TEMPLATE_ID "TMPL6kyYobYJd"
#define BLYNK_TEMPLATE_NAME "ggg"
#define BLYNK_AUTH_TOKEN "nTurBCldnO3iggr2-bVIww62l0RTbatj"
#define BLYNK_PRINT Serial
#include <ESP8266WiFi.h>
#include <BlynkSimpleEsp8266.h>
#include <DHT.h>

// Define your authentication information and Wi-Fi credentials
char auth[] = "nTurBCldnO3iggr2-bVIww62l0RTbatj";
char ssid[] = "D-20-09";
char pass[] = "0189718976";

// Define pins for various sensors and actuators
#define DHT_type DHT11
#define DHT_pin D8
#define soil_moisture_pin A0
#define soil_moisture_VCC D6
#define LDR_VCC D5
#define relay_leds D3
#define relay_fan D4
#define relay_pump D7

// Create a DHT object
DHT dht(DHT_pin, DHT_type);

// Define variables to store sensor data
float humidity = 0;
float temperature = 0;
int light = 0;
int moisture = 0;
float moisture_percentage = 0;

// Create a timer object
SimpleTimer timer;

// Define threshold values for different variables
int lum_thresh = 25;
int moist_thresh = 400;
int hum_thresh = 85;
int temp_thresh = 30;
int pump_timer = 350;
bool leds_ON = false;

// Create LED widget objects
WidgetLED led1(V4);
WidgetLED led2(V5);
WidgetLED led3(V6);

// Setup function: runs once at startup
void setup() {
  // Initialize sensor pins and modes
  // Soil Moisture
  pinMode(soil_moisture_VCC, OUTPUT);
  digitalWrite(soil_moisture_VCC, LOW);
  
  // DHT
  pinMode(DHT_pin, INPUT);
  
  // LDR
  pinMode(LDR_VCC, OUTPUT);
  digitalWrite(LDR_VCC, LOW);
  
  // Relays
  pinMode(relay_pump, OUTPUT);
  digitalWrite(relay_pump, LOW);
  
  pinMode(relay_leds, OUTPUT);
  digitalWrite(relay_leds, LOW);
  
  pinMode(relay_fan, OUTPUT);
  digitalWrite(relay_fan, LOW);
  
  Serial.begin(115200); // Initialize serial communication
  delay(10);
  
  Blynk.begin(auth, ssid, pass); // Initialize Blynk connection
  dht.begin(); // Initialize DHT sensor
  
  // Turn on status LEDs
  led1.on();
  led2.on();
  led3.on();
  
  // Set up the function to be called at regular intervals
  timer.setInterval(10000L, getData);
}


// Main loop function
void loop() {
  Blynk.run(); // Execute Blynk tasks
  timer.run(); // Execute timer tasks
}

// Function to collect and process sensor data
void getData() {
  Serial.println("Analysis Started");
  getDhtData();
  getSoilMoistureData();
  getLightData();
  controlLights();
  controlPump();
  controlFan();
}

// Function to collect DHT sensor data
void getDhtData(void) {
  delay(500);
  float tempIni = temperature;
  float humIni = humidity;
  temperature = dht.readTemperature();
  humidity = dht.readHumidity();
  
  // Check for sensor reading errors
  if (isnan(humidity) || isnan(temperature)) {
    Serial.println("Failed to read from DHT sensor!");
    temperature = tempIni;
    humidity = humIni;
    return;
  }
  
  Serial.print("Temperature: ");
  Serial.print(temperature);
  Serial.println(" °C");
  Serial.print("Humidity: ");
  Serial.print(humidity);
  Serial.println(" %");
  Blynk.virtualWrite(V2, humidity);
  Blynk.virtualWrite(V0, temperature);
}

// Function to collect soil moisture data
void getSoilMoistureData(void) {
  digitalWrite(soil_moisture_VCC, HIGH);
  delay(500);
  moisture = analogRead(soil_moisture_pin);
  moisture_percentage = 100 - ((moisture * 100) / 1023);
  Serial.print("Soil Moisture: ");
  Serial.println(moisture);
  Serial.print("Soil Moisture Percentage: ");
  Serial.print(moisture_percentage);
  Serial.println(" %");
  Blynk.virtualWrite(V3, moisture_percentage);
  digitalWrite(soil_moisture_VCC, LOW);
}

// Function to collect light intensity data
void getLightData(void) {
  delay(500);
  digitalWrite(LDR_VCC, HIGH);
  delay(500);
  light = analogRead(soil_moisture_pin);
  light = (light * 100) / 1024;
  Serial.print("Light Intensity: ");
  Serial.print(light);
  Serial.println(" %");
  Blynk.virtualWrite(V1, light);
  digitalWrite(LDR_VCC, LOW);
}

// Function to control LEDs based on light intensity
void controlLights() {
  if (light < lum_thresh && (!leds_ON)) {
    Serial.println("LEDs ON");
    digitalWrite(relay_leds, LOW);
    Blynk.setProperty(V5, "color", "#00FF2E");
  } else if (light < lum_thresh && leds_ON) {
    Serial.println("LEDs already ON");
  } else {
    Serial.println("LEDs OFF");
    digitalWrite(relay_leds, HIGH);
    Blynk.setProperty(V5, "color", "#FF0000");
  }
  delay(200);
}

// Function to control the water pump
void controlPump() {
  if (moisture < moist_thresh) {
    Serial.println("PUMP OFF");
    digitalWrite(relay_pump, LOW);
    Blynk.setProperty(V4, "color", "#FF0000");
  } else {
    Serial.println("PUMP ON");
    digitalWrite(relay_pump, HIGH);
    Blynk.setProperty(V4, "color", "#00FF2E");
    delay(pump_timer);
    digitalWrite(relay_pump, LOW);
    Blynk.setProperty(V4, "color", "#FF0000");
  }
}

// Function to control the fan based on humidity and temperature
void controlFan() {
  if (humidity > hum_thresh || temperature > temp_thresh) {
    Serial.println("FAN ON");
    digitalWrite(relay_fan, LOW);
    Blynk.setProperty(V6, "color", "#00FF2E");
  } else {
    Serial.println("FAN OFF");
    digitalWrite(relay_fan, HIGH);
    Blynk.setProperty(V6, "color", "#FF0000");
  }
}

// Define pins for sensors and actuators
#define soil_moisture_pin A0
#define soil_moisture_VCC D6
#define relay_pump D7

// Define variables to store sensor data
int moisture = 0;
float moisture_percentage = 0;

// Define threshold values for variables
int moist_thresh = 400;
int pump_timer = 350;

// Setup function: runs once at startup
void setup() {
  // Initialize sensor pins and modes
  // Soil Moisture
  pinMode(soil_moisture_VCC, OUTPUT);
  digitalWrite(soil_moisture_VCC, LOW);
  
  // Relays
  pinMode(relay_pump, OUTPUT);
  digitalWrite(relay_pump, LOW);
  
  Serial.begin(115200); // Initialize serial communication
  delay(10);
}

// Main loop function
void loop() {
  getData();
  delay(10000);
}

// Function to collect and process sensor data
void getData() {
  Serial.println("Analysis Started");
  getSoilMoistureData();
  controlPump();
}

// Function to collect soil moisture data
void getSoilMoistureData(void) {
  digitalWrite(soil_moisture_VCC, HIGH);
  delay(500);
  moisture = analogRead(soil_moisture_pin);
  moisture_percentage = 100 - ((moisture * 100) / 1023);
  Serial.print("Soil Moisture: ");
  Serial.println(moisture);
  Serial.print("Soil Moisture Percentage: ");
  Serial.print(moisture_percentage);
  Serial.println(" %");
  digitalWrite(soil_moisture_VCC, LOW);
}

// Function to control the water pump
void controlPump() {
  if (moisture < moist_thresh) {
    Serial.println("PUMP OFF");
    digitalWrite(relay_pump, LOW);
  } else {
    Serial.println("PUMP ON");
    digitalWrite(relay_pump, HIGH);
    delay(pump_timer);
    digitalWrite(relay_pump, LOW);
  }
}

// Include required libraries
#include <DHT.h>

// Define pins for sensors and actuators
#define DHT_type DHT11
#define DHT_pin D8
#define relay_fan D4

// Create a DHT object
DHT dht(DHT_pin, DHT_type);

// Define variables to store sensor data
float humidity = 0;
float temperature = 0;

// Define threshold values for variables
int hum_thresh = 85;
int temp_thresh = 30;

// Setup function: runs once at startup
void setup() {
  // Initialize sensor pins and modes
  // DHT
  pinMode(DHT_pin, INPUT);
  
  // Relays
  pinMode(relay_fan, OUTPUT);
  digitalWrite(relay_fan, LOW);
  
  Serial.begin(115200); // Initialize serial communication
  delay(10);
  
  dht.begin(); // Initialize DHT sensor
}

// Main loop function
void loop() {
  getData();
  delay(10000);
}

// Function to collect and process sensor data
void getData() {
  Serial.println("Analysis Started");
  getDhtData();
  controlFan();
}

// Function to collect DHT sensor data
void getDhtData(void) {
  delay(500);
  float tempIni = temperature;
  float humIni = humidity;
  temperature = dht.readTemperature();
  humidity = dht.readHumidity();
  
  // Check for sensor reading errors
  if (isnan(humidity) || isnan(temperature)) {
    Serial.println("Failed to read from DHT sensor!");
    temperature = tempIni;
    humidity = humIni;
    return;
  }
  
  Serial.print("Temperature: ");
  Serial.print(temperature);
  Serial.println(" °C");
  Serial.print("Humidity: ");
  Serial.print(humidity);
  Serial.println(" %");
}

// Function to control the fan based on humidity and temperature
void controlFan() {
  if (humidity > hum_thresh || temperature > temp_thresh) {
    Serial.println("FAN ON");
    digitalWrite(relay_fan, LOW);
  } else {
    Serial.println("FAN OFF");
    digitalWrite(relay_fan, HIGH);
  }
}

// Define pins for sensors and actuators
#define LDR_pin A0
#define LDR_VCC D5
#define relay_leds D3

// Define variables to store sensor data
int light = 0;

// Define threshold values for variables
int lum_thresh = 25;
bool leds_ON = false;

// Setup function: runs once at startup
void setup() {
  // Initialize sensor pins and modes
  // LDR
  pinMode(LDR_VCC, OUTPUT);
  digitalWrite(LDR_VCC, LOW);
  
  // Relays
  pinMode(relay_leds, OUTPUT);
  digitalWrite(relay_leds, LOW);
  
  Serial.begin(115200); // Initialize serial communication
  delay(10);
}

// Main loop function
void loop() {
  getData();
  delay(10000);
}

// Function to collect and process sensor data
void getData() {
  Serial.println("Analysis Started");
  getLightData();
  controlLights();
}

// Function to collect light intensity data
void getLightData(void) {
  delay(500);
  digitalWrite(LDR_VCC, HIGH);
  delay(500);
  light = analogRead(LDR_pin);
  light = (light * 100) / 1024;
  Serial.print("Light Intensity: ");
  Serial.println(light);
  Serial.println(" %");
  digitalWrite(LDR_VCC, LOW);
}

// Function to control LEDs based on light intensity
void controlLights() {
  if (light < lum_thresh && (!leds_ON)) {
    Serial.println("LEDs ON");
    digitalWrite(relay_leds, LOW);
  } else if (light < lum_thresh && leds_ON) {
    Serial.println("LEDs already ON");
  } else {
    Serial.println("LEDs OFF");
    digitalWrite(relay_leds, HIGH);
  }
  delay(200);
}

Smart Greenhouse Automation System

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Soil Moisture Sensor & Water Pump Control

Temperature and Humidity Sensor & Fan Control

Light Intensity Sensor & LED Lighting Control

Wi-Fi Connectivity & GUI Dashboard

Final Design

Code